DataWeave programming challenge #7: Modify certain values from a JSON structure

Reader notes

Helpful comments preserved from the original post.

• Sudiptaa · Jun 13, 2023

  Used tree:

  %dw 2.0
  output application/json
  import * from dw::util::Tree
  ---
  payload mapLeafValues ((value, path) ->
  
  if(path.selector contains 'thisname') value else upper(value)
  
   )

• Kenneth Brennan · Jun 13, 2023

  I went with a recursive solution:

  %dw 2.0
  output application/json
  fun capitalizeObject(item: Object) = do{
    fun matchItem(item) = item match{
      case item is Object -> item mapObject ((value, key, index) -> if(key as String == 'thisname') {(key): value} else {(key): matchItem(value)})
      case item is Array -> item map ((item, index) -> matchItem(item))
      case item is String -> upper(item)
    }
    ---
    matchItem(item)
  }
  ---
  capitalizeObject(payload)

• ↳ Reply to Kenneth Brennan

  Alex Martinez · Jun 13, 2023

  I love love love that you're using the do keyword to create a local context. This function's structure can be used for any number of modifications in a recursive way. I love it! The only downside being that if there are more than 255 fields (or recursive calls), you will reach the StackOverflow error. But if it's a small payload like this one, you're all good! Thanks for sharing :D

• ↳ Reply to Alex Martinez

  Kenneth Brennan · Jun 13, 2023

  That pesky stack overflow, I'm not sure how to rewrite this in the same format using tail recursion and match, hard to conceptualize. Might give it another go when I get some free time. Thanks for posting these challenges, I enjoyed this one!

• Shyam Raj Prasad · Jun 13, 2023

  My solution is similar to yours with extra type check of string.

  %dw 2.0
  output application/json
  import * from dw::util::Tree
  ---
  payload mapLeafValues ((value, path) ->
    if(!(path[-1].selector == "thisname") and value is String) upper(value) else value
  )

FAQs

Frequently asked questions about this post.

• What is the goal of DataWeave programming challenge #7?

  The challenge is to create a DataWeave script that updates all the values in a JSON structure to uppercase, except the ones whose field equals thisname. For example, the field name with value "a" becomes "A", but the field thisname with value "def" stays the same.

• Which DataWeave function does this challenge use to walk the JSON structure?

  It uses the mapLeafValues function from the dw::util::Tree module, which lets you transform each leaf value in the structure. Both provided solutions import mapLeafValues from dw::util::Tree and call it on the payload.

• How do I skip the `thisname` field while uppercasing everything else?

  Inside mapLeafValues, you check the field name of each value with path[-1].selector and compare it to the string "thisname"; if it matches you return the value unchanged, otherwise you apply the upper function to convert it to uppercase.

• What does `path[-1].selector` do in the solution?

  As described in Clue #4, path[-1].selector retrieves the name of each value's field so you can compare it with a given string value, which is how the script decides whether a value belongs to the thisname field and should be left alone.

• What's the difference between the two provided solutions?

  Solution #1 uses the explicit lambda form mapLeafValues ((value, path) -> ...) and references the field name with path[-1].selector, while Solution #2 uses the shorthand anonymous-parameter form, referencing the value with $ and the field name with $$[-1].selector; both produce the same result.

More from this series