DataWeave programming challenge #6: Using tail-recursion to get the factorial of a number

Reader notes

Helpful comments preserved from the original post.

• Nicky van Steensel van der Aa · Jul 18, 2023

  For those using dw::core::Arrays slice it excludes the last index, so select 20-26

• Nicky van Steensel van der Aa · Jul 18, 2023

  %dw 2.0
  output application/json
  
  fun solve(x)=
  x reduce (item, acc) -> ( (if(item > 0) acc + factorial(item) else acc))
  
  fun factorial(x)=
  2 to x reduce (item, acc) -> (acc*item)
  
  ---
  
  (solve(payload splitBy('\n')) splitBy(''))[20 to 25] joinBy("")

• Nirmala Vairaganthan · May 10, 2023

  %dw 2.0
  fun factorial(num)= num to 1 reduce ((item, accumulator) -> accumulator * item)
  fun pos(val) = val[20 to 25]
  ---
  pos(sum((payload splitBy "\n" ) map factorial($))) as Number

• Disha Bhar · May 10, 2023

  Tried this out. :)

  %dw 2.0
  import * from dw::core::Strings
  fun tailFactorial(n:Number, p:Number = 1) =
      (if(n == 1 or n == 0)
          p
      else
          tailFactorial(n-1, (p * n)))
  output application/json
  ---
  (sum((payload splitBy "\n") filter($>0) map tailFactorial($ as Number) )as String)[20 to 25] as Number

• Felix Schnabel · May 9, 2023

  %dw 2.0
  output application/json
  import * from dw::core::Strings
  @TailRec
  fun solve(i: Number, acc: Number = 1): Number = i match {
      case 0 -> acc
      case i if(i < 0) -> 0
      else -> solve(i - 1, acc * i)
  }
  ---
  lines(payload)
      map solve($ as Number)
      then sum($)
      then $[20 to 25] as Number

• Sudiptaa · May 9, 2023

  %dw 2.0
  output application/json
  
  import lines from dw::core::Strings
  
  fun factorial(n:Number,res:Number=1):Number = if (n == 1 or n ==0) res
  
      else if (n < 0) 0
  
      else factorial(n - 1,res * n)
  ---
  
  sum(lines(payload) map factorial($))[20 to 25] as Number

• Shyam Raj Prasad · May 9, 2023

  Solved using reduce.

  %dw 2.0
  import lines from dw::core::Strings
  output application/json
  fun factorial(x) = 1 to x reduce ((item, accumulator) -> 
      accumulator * item
  )
  
  ---
  ((lines(payload) filter ($>0) reduce ((item, accumulator) ->
      factorial(item) + accumulator
   )) as String)[20 to 25] as Number

FAQs

Frequently asked questions about this post.

• What is this DataWeave challenge asking me to do?

  The challenge asks you to create a tail-recursive function that gets the factorial of each positive number in the payload, sum the results, then retrieve the digits located at positions 20 to 25, returning a number and not a string. Numbers that are 0 or less aren't calculated, so for the sample input the factorial of 3 is 6, the factorial of 5 is 120, the factorial of -6 isn't calculated (treated as 0), and the expected output is 537046.

• How do I process every line of the input payload?

  As the clues suggest, you can use lines() from the Strings module or splitBy() to process every line of the payload, which can be in txt format.

• Why does the post insist on tail-recursion instead of regular recursion?

  The clues warn that you must use tail-recursiveness and not regular recursiveness, otherwise your script might not work.

• How do I avoid an infinite loop in the recursive factorial function?

  Make sure to create an if statement before calling the function in recursion; otherwise you might get stuck in an infinite loop, as noted in the clues.

• How do I return a number instead of a string for the final result?

  You can use the keyword as to transform to and from strings and numbers, and you extract the characters at positions 20 to 25 from a string using the range selector [ x to y ] before converting the result back to a number.

• Where should I look for help while solving this challenge?

  The post recommends referring only to the DataWeave documentation at https://docs.mulesoft.com/dataweave/latest/ and avoiding Google or asking others, so you can learn on your own; you can also solve it directly on the linked DataWeave Playground.

More from this series